Trailing $0$ s in $(10!)!$

// Compiles with `gcc -nostdlib`. On 64-bit machines, use the `-m32` flag also.
#define SYS_EXIT    $1
#define SYS_WRITE   $4

#define STDOUT      $1

#define TENFAC $3628800

.global _start
.text

/* void* itoa(int, char *) 
   - char * points to the *back* of the string. itoa writes from ls digit.
   - clobbers edi, eax, edx
   - returns pointer to beginning of string as eax
*/
itoa:
    pushl   %ebp
    movl    %esp, %ebp

    movl    8(%esp), %edi
    movl    12(%esp), %eax

    cycledigits:
        xorl    %edx, %edx
        divl    decimal
        addl    $48, %edx       // Add 48 to remainder, store digit
        movb    %dl, (%edi)     // Copy char
        decl    %edi            // Next digit
        cmpl    $0, %eax
        jg      cycledigits     // No more digits?

    leal    1(%edi), %eax       // return value

    popl    %ebp
    ret

_start:
    /* Entry Point: */
    movl %esp, %ebp         // Stack setup

    movl $5, %ebx           // Denominator
    movl $5, %edi           // multiply by this
    movl $0, %esi           // Accumulator

loopbody:
    xorl %edx, %edx
    movl TENFAC, %eax       // Dividend always ten factorial
    divl %ebx
    cmpl $0, %eax
    je display
    addl %eax, %esi
    movl %ebx, %eax
    mull %edi
    movl %eax, %ebx
    jmp loopbody

display:
    pushl %esi
    pushl $numstring
    call itoa
    addl $8, %esp
    movl %eax, %ecx         // Address of ptr
    subl $numstring, %eax
    negl %eax
    leal 2(%eax), %edx      // characters to display (including linefeed)
    /*
        Linefeed SHOULDN'T be necessary, but in case your terminal flushes the output line like mine does, we want it to display. Also, it looks cleaner.
    */
    movl STDOUT, %ebx
    movl SYS_WRITE, %eax
    int  $0x80

exit:
    movl    SYS_EXIT, %eax
    xorl    %ebx, %ebx              // The exit code.
    int     $0x80

.data
    /* Begin Data Section: */
    decimal:  // base 10
        .long 10
    buffer:
        .ascii "xxxxxxxxxx"
    numstring:
        .byte 'x
    linebreak:
        .byte '\n